Debug builds: SRTP-constrained inline member runs the first call's specialization for later calls with other type arguments #20826

module Lib

open System

let inline create (x: ^a) : Result< ^b, 'c > =
    ((^a or ^b): (static member create: ^a -> Result< ^b, 'c >) x)

type Builder() =
    member val Registered = ResizeArray<string>()

    member this.Convert<'a, 'b>(f: Func<'a, 'b>) =
        this.Registered.Add($"{typeof<'a>.Name}->{typeof<'b>.Name}")
        this

type Builder with
    [<RequiresExplicitTypeArguments>]
    member inline this.Register<'domain, 'serialized
        when ('serialized or 'domain): (static member create: 'serialized -> Result<'domain, string>)
        and (^domain or ^serialized): (static member op_Explicit: ^domain -> ^serialized)>
        ()
        =
        let parse x =
            match create x with
            | Ok x -> x
            | Error(msg: string) -> failwith msg

        let getValue x =
            ((^domain or ^serialized): (static member op_Explicit: ^domain -> ^serialized) x)

        this.Convert<'serialized, 'domain>(parse).Convert<'domain, 'serialized>(getValue) |> ignore
        this

open Lib

type A =
    | A of string
    static member create(s: string) = Ok(A s)
    static member op_Explicit(A s) : string = s

type B =
    | B of int
    static member create(i: int) = Ok(B i)
    static member op_Explicit(B i) : int = i

let b = Builder()
b.Register<A, string>() |> ignore
b.Register<B, int>() |> ignore

printfn "%s" (String.concat ", " b.Registered)