python-embed/build.gradle at main · howtis/python-embed · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
plugins {
    id 'java'
    id 'jacoco'
    id 'com.vanniktech.maven.publish' version '0.37.0'
}

group = 'io.github.howtis'

repositories {
    mavenCentral()
}

subprojects {
    group = rootProject.group

    apply plugin: 'java'
    apply plugin: 'jacoco'
    apply plugin: 'com.vanniktech.maven.publish'

    repositories {
        mavenCentral()
    }

    java {
        withSourcesJar()
        toolchain {
            languageVersion = JavaLanguageVersion.of(17)
        }
    }

    mavenPublishing {
        publishToMavenCentral(true)
        signAllPublications()
        //noinspection GroovyAssignabilityCheck
        pom {
            name = 'python-embed'
            description = 'Embed Python in Java applications'
            url = 'https://github.com/howtis/python-embed'
            licenses {
                license {
                    name = 'MIT License'
                    url = 'https://opensource.org/licenses/MIT'
                }
            }
            developers {
                developer {
                    id = 'howtis'
                    name = 'howtis'
                    url = 'https://github.com/howtis'
                }
            }
            scm {
                url = 'https://github.com/howtis/python-embed'
                connection = 'scm:git:git://github.com/howtis/python-embed.git'
                developerConnection = 'scm:git:ssh://github.com/howtis/python-embed.git'
            }
        }
    }

    tasks.named('sourcesJar') {
        dependsOn(tasks.matching { it.name == 'generatePythonEmbedProperties' })
        dependsOn(tasks.matching { it.name == 'createVenv' })
    }

    tasks.named('jar') {
        metaInf {
            from rootProject.file('LICENSE')
        }
    }

    tasks.withType(Test).configureEach {
        useJUnitPlatform()
        systemProperty 'junit.jupiter.execution.parallel.enabled', 'true'
        systemProperty 'junit.jupiter.execution.parallel.mode.default', 'same_thread'
        systemProperty 'junit.jupiter.execution.parallel.mode.classes.default', 'concurrent'
        finalizedBy(tasks.matching { it.name == 'jacocoTestReport' })
    }

    jacocoTestReport {
        dependsOn test
        reports {
            xml.required = true
            html.required = true
        }
    }
}

tasks.named('test') {
    dependsOn gradle.includedBuild('python-embed-build-common').task(':test')
    dependsOn gradle.includedBuild('python-embed-gradle-plugin').task(':test')
    dependsOn gradle.includedBuild('python-embed-maven-plugin').task(':test')
}