gradle-concourse-plugin/build.gradle at develop · cinchapi/gradle-concourse-plugin · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
/*
 * Copyright (c) 2016-2024 Cinchapi Inc.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

plugins {
    id 'groovy'
    id 'java-gradle-plugin'
    id 'com.gradle.plugin-publish' version '1.3.0'
    id 'maven-publish'
    id 'signing'
}

group = 'com.cinchapi'
version = '1.2.0'

java {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
    withSourcesJar()
    withJavadocJar()
}

repositories {
    mavenCentral()
}

dependencies {
    implementation gradleApi()
    testImplementation 'junit:junit:4.13.2'
}

gradlePlugin {
    website = 'https://github.com/cinchapi/gradle-concourse-plugin'
    vcsUrl = 'https://github.com/cinchapi/gradle-concourse-plugin'

    plugins {
        concoursePlugin {
            id = 'com.cinchapi.concourse-plugin'
            displayName = 'Concourse Plugin Bundle'
            description = 'A Gradle plugin to bundle Concourse plugins.'
            tags.set(['concourse', 'distribution'])
            implementationClass = 'com.cinchapi.gradle.concourse.plugin.ConcoursePluginPlugin'
        }
    }
}

publishing {
    publications {
        pluginMaven(MavenPublication) {
            pom {
                name = 'Gradle Concourse Plugin'
                description = 'A Gradle plugin to bundle Concourse plugins.'
                url = 'https://github.com/cinchapi/gradle-concourse-plugin'
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'jnelson'
                        name = 'Jeff Nelson'
                        email = 'jeff@cinchapi.com'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/cinchapi/gradle-concourse-plugin.git'
                    developerConnection = 'scm:git:ssh://github.com:cinchapi/gradle-concourse-plugin.git'
                    url = 'https://github.com/cinchapi/gradle-concourse-plugin'
                }
            }
        }
    }
}

signing {
    // Only sign if signing credentials are available
    required { gradle.taskGraph.hasTask('publish') }
    sign publishing.publications
}

tasks.withType(Sign).configureEach {
    onlyIf { project.hasProperty('signing.keyId') }
}