Is it possible to add color formatting to the Alphabet class?

[THEkatinamicrowave]

The mod director said he wanted colored text for the uhhh the titlestate which is fine because we have a custom titlestate but since the Alphabet class no longer stores every letter publicly I'm unsure how to go about this. Is it possible? We're on 1.0.1 btw none of the test commits

[r6915ee]

Are you referring to applying color to only specific parts of the text?

[THEkatinamicrowave]

I mean we totally could just make an Alphabet.hx in source/ and override draw(). I think, anyway. I'm unsure; I'm pretty sure I saw something similar to that in Ne_Eo's Celeste project.

[r6915ee]

I suppose that could work, but then again, you may need to consider blit rendering as well; I've heard that can be quite troubling to work with.

[THEkatinamicrowave]

I did a bit of researchering and I think I found a way using Alphabet's effects and __renderData properties
I'll get back to this post once I finalize my idea but like yeah just stick around for now

[THEkatinamicrowave]

UPDATE:
Here's the full class. Implement using [Alphabet instance].effects.push([MarkupEffect instance]);.

MarkupEffect.hx:

package funkin.menus.ui.effects;

import flixel.util.FlxColor;
import flixel.util.helpers.FlxRange;
import funkin.menus.ui.effects.RegionEffect;

class MarkupEffect extends RegionEffect
{
	public var char:UnicodeString;
	public var color:FlxColor;
	public var borderColor:FlxColor;

	public function new(char:UnicodeString, color:FlxColor = 0xFFFFFFFF, borderColor:FlxColor = 0xFF000000)
	{
		super();

		this.char = char;
		this.color = color;
		this.borderColor = borderColor;

		if (borderColor != 0xFF000000) trace('MarkupEffects do not yet support borderColors for Alphabet');
	}

	public function getMarkRanges(text:String):Array<FlxRange<Int>>
	{
		var ranges:Array<FlxRange<Int>> = [];
		var first:Int = -1;

		for (i in 0...text.length) {
			if (text.charAt(i) == char) {
				if (first == -1) {
					first = i;
				} else {
					var second = i;
					ranges.push(new FlxRange<Int>(first, second));
					first = -1;
				}
			}
		}

		return ranges;
	}

	override public function willModify(index:Int, lineIndex:Int, renderData:AlphabetRenderData):Bool
	{
		for (r in getMarkRanges(renderData.parent.text)) {
			if (index >= r.start && index <= r.end)
				return (true && super.willModify(index, lineIndex, renderData));
		}

		return false;
	}

	override public function modify(index:Int, lineIndex:Int, renderData:AlphabetRenderData):Void
	{
		if (renderData.letter == char) {
			renderData.letter = "字";
			return;
		}

		for (r in getMarkRanges(renderData.parent.text)) {
			if (index >= r.start && index <= r.end) {
				renderData.red   = color.redFloat;
				renderData.green = color.greenFloat;
				renderData.blue  = color.blueFloat;
				renderData.alpha = color.alphaFloat;
				break;
			}
		}
	}
}

Side note: you do have to add "字" as a non-character animation. I set mine to a new frame with xywh=0,0,1,1. This is temporary, as I imagine there's a better way of going about this than gatekeeping some random niche character.

[THEkatinamicrowave]

oh yeah also I had been working on bordercolors but it was being really annoying and required editing Alphabet class, which I don't like doing.