[Infrastructure] Allow building a workflow as a workflow plugin

A workflow opts in with WORKFLOW_PLUGIN on o2physics_add_dpl_workflow.
Its sources, with the shared precompiled header as before, are then
compiled once, into the DSO libO2Physics<Name>Plugin holding the DPL
workflow plugin <Name>, the CamelCase of the executable name without
o2-, which o2-dpl-run can load with --workflow-plugin. The executable
keeps its name and options and only has a main() calling the plugin it
links, which it runs as its embedded workflow. Workflows which do not
opt in are built as before. The histograms tutorial opts in.

It needs the matching O2 change, which adds WORKFLOW_PLUGIN to
o2_add_dpl_workflow and dpl_workflow_main() to runDataProcessing.h.

Author: ktf

Tutorials/CMakeLists.txt

@@ -60,7 +60,8 @@ o2physics_add_dpl_workflow(dynamic-columns
 o2physics_add_dpl_workflow(histograms
                   SOURCES src/histograms.cxx
                   PUBLIC_LINK_LIBRARIES O2::Framework
-                  COMPONENT_NAME AnalysisTutorial)
+                  COMPONENT_NAME AnalysisTutorial
+                  WORKFLOW_PLUGIN)
 
 o2physics_add_dpl_workflow(histograms-full-tracks
                   SOURCES src/histogramsFullTracks.cxx

cmake/O2PhysicsAddWorkflow.cmake

@@ -25,27 +25,67 @@ include_guard()
 # The installed JSON file will be named <executable-name>.json and installed
 # under share/dpl directory
 #
+# With WORKFLOW_PLUGIN, the sources are compiled into the DPL workflow plugin
+# <Name>, in libO2Physics<Name>Plugin, which o2-dpl-run can load with
+# --workflow-plugin, and the executable is only a main() linking it. <Name> is
+# the CamelCase of the executable name without o2-.
+#
 
 function(o2physics_add_dpl_workflow baseTargetName)
-  cmake_parse_arguments(PARSE_ARGV 1 A "" "COMPONENT_NAME;TARGETVARNAME;REUSE_FROM"
+  cmake_parse_arguments(PARSE_ARGV 1 A "WORKFLOW_PLUGIN" "COMPONENT_NAME;TARGETVARNAME;REUSE_FROM"
                         "SOURCES;PUBLIC_LINK_LIBRARIES")
 
   if(A_UNPARSED_ARGUMENTS)
     message(FATAL_ERROR "Got trailing arguments ${A_UNPARSED_ARGUMENTS}")
   endif()
 
-  o2physics_add_executable(${baseTargetName}
-    COMPONENT_NAME ${A_COMPONENT_NAME} TARGETVARNAME targetExeName
-    SOURCES ${A_SOURCES}
-    PUBLIC_LINK_LIBRARIES O2::Framework ${A_PUBLIC_LINK_LIBRARIES})
+  set(compileTarget "")
+  if(A_WORKFLOW_PLUGIN)
+    if(NOT TARGET O2PhysicsWorkflowMain)
+      file(CONFIGURE OUTPUT ${CMAKE_BINARY_DIR}/O2PhysicsWorkflowMain.cxx CONTENT [[
+extern "C" int dpl_workflow_main(int argc, char** argv);
+int main(int argc, char** argv) { return dpl_workflow_main(argc, argv); }
+]])
+      add_library(O2PhysicsWorkflowMain OBJECT ${CMAKE_BINARY_DIR}/O2PhysicsWorkflowMain.cxx)
+    endif()
+    # Callers may pass JOB_POOL among the sources, for o2physics_add_executable.
+    cmake_parse_arguments(S "" "JOB_POOL" "" ${A_SOURCES})
+    o2physics_add_executable(${baseTargetName}
+      COMPONENT_NAME ${A_COMPONENT_NAME} TARGETVARNAME targetExeName
+      SOURCES $<TARGET_OBJECTS:O2PhysicsWorkflowMain>
+      PUBLIC_LINK_LIBRARIES O2::Framework ${A_PUBLIC_LINK_LIBRARIES})
+    get_target_property(name ${targetExeName} OUTPUT_NAME)
+    string(REGEX REPLACE "^o2-" "" name ${name})
+    string(REPLACE "-" ";" parts ${name})
+    set(name "")
+    foreach(part IN LISTS parts)
+      string(SUBSTRING ${part} 0 1 first)
+      string(SUBSTRING ${part} 1 -1 rest)
+      string(TOUPPER ${first} first)
+      string(APPEND name ${first}${rest})
+    endforeach()
+    string(MAKE_C_IDENTIFIER ${name} name)
+    set(compileTarget O2Physics${name}Plugin)
+    add_library(${compileTarget} SHARED ${S_UNPARSED_ARGUMENTS})
+    target_link_libraries(${compileTarget} PUBLIC O2::Framework ${A_PUBLIC_LINK_LIBRARIES})
+    target_compile_definitions(${compileTarget} PRIVATE DPL_WORKFLOW_PLUGIN_NAME=${name})
+    target_link_libraries(${targetExeName} PUBLIC ${compileTarget})
+    install(TARGETS ${compileTarget} LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})
+  else()
+    o2physics_add_executable(${baseTargetName}
+      COMPONENT_NAME ${A_COMPONENT_NAME} TARGETVARNAME targetExeName
+      SOURCES ${A_SOURCES}
+      PUBLIC_LINK_LIBRARIES O2::Framework ${A_PUBLIC_LINK_LIBRARIES})
+    set(compileTarget ${targetExeName})
+  endif()
 
   if(A_TARGETVARNAME)
     set(${A_TARGETVARNAME}
         ${targetExeName}
         PARENT_SCOPE)
   endif()
-  set_property(TARGET ${targetExeName} PROPERTY JOB_POOL_COMPILE analysis)
-  set_property(TARGET ${targetExeName} PROPERTY JOB_POOL_LINK analysis)
+  set_property(TARGET ${compileTarget} PROPERTY JOB_POOL_COMPILE analysis)
+  set_property(TARGET ${compileTarget} ${targetExeName} PROPERTY JOB_POOL_LINK analysis)
 
   # Reuse a precompiled header. Without an explicit REUSE_FROM, fall back to the
   # shared AnalysisPCH (Common/Core): a workflow translation unit spends most of
@@ -63,7 +103,7 @@ function(o2physics_add_dpl_workflow baseTargetName)
   endif()
   # A target cannot reuse its own PCH, and the carrier is not built when recc
   # is caching compilations remotely instead.
-  if(_pch AND NOT _pch STREQUAL targetExeName AND NOT DEFINED ENV{USE_RECC})
+  if(_pch AND NOT _pch STREQUAL compileTarget AND NOT DEFINED ENV{USE_RECC})
     # GCC refuses a PCH built with a different preprocessor state than the
     # consumer's, and -Werror turns that refusal into a build failure:
     #   cmake_pch.hxx.gch: not used because `RANS_ENABLE_JSON' not defined
@@ -87,8 +127,8 @@ function(o2physics_add_dpl_workflow baseTargetName)
     # preprocessor state the carrier compiled with, and that state is exactly
     # what GCC compares, rather than one property of it at a time.
     # Requires CMake >= 3.27.
-    target_link_libraries(${targetExeName} PRIVATE $<COMPILE_ONLY:${_pch}>)
-    target_precompile_headers(${targetExeName} REUSE_FROM ${_pch})
+    target_link_libraries(${compileTarget} PRIVATE $<COMPILE_ONLY:${_pch}>)
+    target_precompile_headers(${compileTarget} REUSE_FROM ${_pch})
   endif()
 
   set(jsonFile $<TARGET_FILE_BASE_NAME:${targetExeName}>.json)